Arduino에 카드리더기 연결 (Use magnetic card reader with Arduino)

Arduino에 Magtek의 magnetic strip reader를 연결하여 보았다.

현재 가지고 있는 리더기는 TTL 인터페이스를 가지고 있는 single track reader이다. 5핀 커넥터를 가지고 있고 Vcc, GND, Card present, Clock(Strobe), Data 신호를 제공해 준다.

신호 타이밍은 아래와 같다.

Arduino의 D2, D3, D5를 각각 리더기의 Data, Clock, Card present에 연결해 주면 된다.

코드는 다음과 같다.

View source code

/*
* Magnetic Stripe Reader
* by Stephan King http://www.kingsdesign.com
*
* Reads a magnetic stripe.
*
*/

int cld1Pin = 5;            // Card status pin
int rdtPin = 2;             // Data pin
int reading = 0;            // Reading status
volatile int buffer[400];   // Buffer for data
volatile int i = 0;         // Buffer counter
volatile int bit = 0;       // global bita
char cardData[40];          // holds card info
int charCount = 0;          // counter for info
int DEBUG = 0;

void setup() {
  Serial.begin(38400);

  // The interrupts are key to reliable
  // reading of the clock and data feed
  attachInterrupt(0, changeBit, CHANGE);
  attachInterrupt(1, writeBit, FALLING);
}

void loop(){

  // Active when card present
  while(digitalRead(cld1Pin) == LOW){
   reading = 1;
  }    

  // Active when read is complete
  // Reset the buffer
  if(reading == 1) { 

   if (DEBUG == 1) {
     printBuffer();
   }

   decode();
   reading = 0;
   i = 0;

   int l;
   for (l = 0; l < 40; l = l + 1) {
     cardData[l] = '\n';
   }

   charCount = 0;
  }
}

// Flips the global bit
void changeBit(){
  if (bit == 0) {
   bit = 1;
  } else {
   bit = 0;
  }
}

// Writes the bit to the buffer
void writeBit(){
  buffer[i] = bit;
  i++;
}

// prints the buffer
void printBuffer(){
  int j;
  for (j = 0; j < 200; j = j + 1) {
   Serial.println(buffer[j]);
  }
}

int getStartSentinal(){
  int j;
  int queue[5];
  int sentinal = 0;

  for (j = 0; j < 400; j = j + 1) {
   queue[4] = queue[3];
   queue[3] = queue[2];
   queue[2] = queue[1];
   queue[1] = queue[0];
   queue[0] = buffer[j];

   if (DEBUG == 1) {
     Serial.print(queue[0]);
     Serial.print(queue[1]);
     Serial.print(queue[2]);
     Serial.print(queue[3]);
     Serial.println(queue[4]);
   }

   if (queue[0] == 0 & queue[1] == 1 & queue[2] == 0 & queue[3] == 1 & queue[4] == 1) {
     sentinal = j - 4;
     break;
   }
  }

  if (DEBUG == 1) {
   Serial.print("sentinal:");
   Serial.println(sentinal);
   Serial.println("");
  }

  return sentinal;
}

void decode() {
  int sentinal = getStartSentinal();
  int j;
  int i = 0;
  int k = 0;
  int thisByte[5];

  for (j = sentinal; j < 400 - sentinal; j = j + 1) {
   thisByte[i] = buffer[j];
   i++;
   if (i % 5 == 0) {
     i = 0;
     if (thisByte[0] == 0 & thisByte[1] == 0 & thisByte[2] == 0 & thisByte[3] == 0 & thisByte[4] == 0) {
       break;
     }
     printMyByte(thisByte);
   }
  }

  Serial.print("Stripe_Data:");
  for (k = 0; k < charCount; k = k + 1) {
   Serial.print(cardData[k]);
  }
  Serial.println("");

}

void printMyByte(int thisByte[]) {
  int i;
  for (i = 0; i < 5; i = i + 1) {
   if (DEBUG == 1) {
     Serial.print(thisByte[i]);
   }
}
   if (DEBUG == 1) {
     Serial.print("\t");
     Serial.print(decodeByte(thisByte));
     Serial.println("");
   }

   cardData[charCount] = decodeByte(thisByte);
   charCount ++;
}

char decodeByte(int thisByte[]) {
   if (thisByte[0] == 0 & thisByte[1] == 0 & thisByte[2] == 0 & thisByte[3] == 0 & thisByte[4] == 1){
     return '0';
   }
   if (thisByte[0] == 1 & thisByte[1] == 0 & thisByte[2] == 0 & thisByte[3] == 0 & thisByte[4] == 0){
     return '1';
   }

   if (thisByte[0] == 0 & thisByte[1] == 1 & thisByte[2] == 0 & thisByte[3] == 0 & thisByte[4] == 0){
     return '2';
   }

   if (thisByte[0] == 1 & thisByte[1] == 1 & thisByte[2] == 0 & thisByte[3] == 0 & thisByte[4] == 1){
     return '3';
   }

   if (thisByte[0] == 0 & thisByte[1] == 0 & thisByte[2] == 1 & thisByte[3] == 0 & thisByte[4] == 0){
     return '4';
   }

   if (thisByte[0] == 1 & thisByte[1] == 0 & thisByte[2] == 1 & thisByte[3] == 0 & thisByte[4] == 1){
     return '5';
   }

   if (thisByte[0] == 0 & thisByte[1] == 1 & thisByte[2] == 1 & thisByte[3] == 0 & thisByte[4] == 1){
     return '6';
   }

   if (thisByte[0] == 1 & thisByte[1] == 1 & thisByte[2] == 1 & thisByte[3] == 0 & thisByte[4] == 0){
     return '7';
   }

   if (thisByte[0] == 0 & thisByte[1] == 0 & thisByte[2] == 0 & thisByte[3] == 1 & thisByte[4] == 0){
     return '8';
   }

   if (thisByte[0] == 1 & thisByte[1] == 0 & thisByte[2] == 0 & thisByte[3] == 1 & thisByte[4] == 1){
     return '9';
   }

   if (thisByte[0] == 0 & thisByte[1] == 1 & thisByte[2] == 0 & thisByte[3] == 1 & thisByte[4] == 1){
     return ':';
   }

   if (thisByte[0] == 1 & thisByte[1] == 1 & thisByte[2] == 0 & thisByte[3] == 1 & thisByte[4] == 0){
     return ';';
   }

   if (thisByte[0] == 0 & thisByte[1] == 0 & thisByte[2] == 1 & thisByte[3] == 1 & thisByte[4] == 1){
     return '<';
   }

   if (thisByte[0] == 1 & thisByte[1] == 0 & thisByte[2] == 1 & thisByte[3] == 1 & thisByte[4] == 0){
     return '=';
   }

   if (thisByte[0] == 0 & thisByte[1] == 1 & thisByte[2] == 1 & thisByte[3] == 1 & thisByte[4] == 0){
     return '>';
   }

   if (thisByte[0] == 1 & thisByte[1] == 1 & thisByte[2] == 1 & thisByte[3] == 1 & thisByte[4] == 1){
     return '?';
   }
}

카드를 리더기에 긁어주면 아래와 같이 카드의 데이터가 시리얼포트로 출력된다.

문제점은 위의 코드로는 디코딩 루틴이 카드를 정방향인 경우에만 동작하고 반대 방향으로 긁어주는 경우에는 데이터를 정상적으로 디코딩 해 주지 못한다. 역방향인 경우도 정상적으로 디코딩이 가능하도록 코드를 수정 할 예정이다.

PD2437을 Arduino에서 사용하기 (Connect PD2437 (5x7 character 4-digit display) to Arduino)

동네의 부품샵을 구경하다 우연히 구하게 된 부품이다. 저렴한 가격($1.99)때문에 메뉴얼 여부에 관계 없이 일단 구입하여 버렸다. 물론 '구글신'을 믿고 있었기 때문이지만...

부품 명칭은 PD2437로 OSRAM에서 나온 4-character 5x7 dot matrix alphanumeric programmable display with built-in CMOS control functions 이다. DIL 패키지 안에 5x7 매트릭스가 4개 들어있고 디스플레이 컨트롤러를 내장하고 있다.

이 부품을 사용하기 위해 구글의 도움으로 유저메뉴얼과 어플리케이션 노트를 찾아내었다.

pd2437.pdf

PD243x_App.pdf

일반적인 메모리같이 8-bit bidirectional data bus를 사용해서 마이크로컨트롤러와 데이터를 교환하고 ASCII 코드를 입력받아 그에 해당하는 문자를 표시하게 되어 있었다.

Arduino에 연결하려고 하는데 8-bit data bus를 모두 digital i/o에 연결해 버리면 arduino에 다른 주변기기를 붙일 수 없을거 같아 74LS164(8-Bit Parallel-Out Serial-In Shift Registers)를 같이 사용하기로 하였다.

이를 토대로 구성한 회로는 다음과 같다.

Arduino의 D2-D9까지를 사용하였다.

실제 기판에 만들기 전에 먼저 브레드보드에서 프로토타입으로 확인을 해 보았다.

큰 문제 없이 원하는 글자를 표시해 주었다. 테스트에 사용한 코드는 다음과 같다.

View source code

/*
* PD2437 Test
*/

/*

- Addressing
  0xx : control word
  100 : digit 0 (rightmost)
  101 : digit 1
  110 : digit 2
  111 : digit 3 (leftmost)

- Control Word
  b7 : clear
      0 standard operation
      1 clear entire display
  b6 : lamp test
      0 standard operation
      1 display all dots at 50% brightness
  b5 : blink
      0 blink attribute disabled
      1 blink entire display
  b4 : attribute enable
      0 disable above attributes
      1 enable above attributes
  b3,b2: attributes
      00 display cursor instead of character
      01 blink character
      10 display blinking cursor instead of character
      11 alternate character with cursor
  b1,b0: brightness
      00 0% (black)
      01 25%
      10 50%
      11 100%
     
  -----------------------------------------------------
  how to load information into the display
 
   SET BRIGHTNESS
  1. set brightness level of the entire display to your preference, (000) <- 0x02 (50%)
  
   LOAD FOUR CHARACTERS
  2. load "S" in the left hand digit, (111) <- 'S'
  3. load "T" in the next digit, (110) <- 'T'
  4. load "O" in the next digit, (101) <- 'O'
  5. load "P" in the right hand digit, (100) <- 'P'
 
   BLINK A SINGLE CHARACTER
  6. into the digit, second from the right, load the hex code 0xcf, which is the code for an 'O' with the d7 bit added as a control bit, (101) <- 0xcf
  7. load enabled blinking character into the control word register. the display should show "STOP" with a flashing "O", (000) <- 0x17
 
   ADD ANOTHER BLINKING CHARACTER
  8. into the left hand digit, load the he code 0xd3 which gives an 'S' with d7 bit added as a control bit, (111) <- 0xd3
 
   ALTERNATE CHARACTER/CURSOR ENABLE
  9. load enable alternate character/cursor into the control word register. the display now should show "STOP" with the 'O' and the 'S' alternating between the letter and cursor. (000) <- 1f
 
   INITIATE FOUR CHARACTER BLINKING
  10. load enable display blinking. the display now should show the entire word "STOP" blinking, (000) <- 0x23
*/

// Connected to LS164
int DATA = 2;    // LS164 Din  (pin 1&2)
int CLK = 3;     // LS164 Clk  (pin 8)

// Connected to PD2437
int A0 = 6;   // Address 0 (pin 7)
int A1 = 5;   // Address 1 (pin 8)
int A2 = 4;   // Address 2 (pin 9)

int WR = 7;   // Write (pin 11)
int CE = 8;   // Chip Enable (NEG, pin 6)
int RST = 9;  // Reset (NEG, pin 4)

void setup()                    // run once, when the sketch starts
{
  Serial.begin(38400);
 
  // pins for LS164
  pinMode(DATA, OUTPUT);      // sets the digital pin as output
  pinMode(CLK, OUTPUT);      // sets the digital pin as output
 
  // pins for PD2437
  pinMode(A0, OUTPUT);
  pinMode(A1, OUTPUT);
  pinMode(A2, OUTPUT);
  pinMode(WR, OUTPUT);
  pinMode(CE, OUTPUT);
  pinMode(RST, OUTPUT);
 
  // Reset PD2437
  digitalWrite(CE, HIGH);
  digitalWrite(WR, HIGH);

  digitalWrite(RST, LOW);
  digitalWrite(RST, HIGH);
}

void loop()                     // run over and over again
{
  putChar(0, 0x83);
  delay(100);
  putChar(7,'S');
  delay(100);
  putChar(6,'T');
  delay(100);
  putChar(5,'O');
  delay(100);
  putChar(4,'P');
  delay(100);
 
  putChar(4, 'P' | 0x80);    // 'P' w/ MSB
  delay(100);
  putChar(0, 0x17);
  delay(100);
  putChar(7, 'S' | 0x80);    // 'S' w/ MSB
  delay(100);
  putChar(0, 0x1f);
  delay(100);
  putChar(0, 0x23);
 
  delay(1000); 
}

//
// Subroutine for LS164
//

// Send byte to LS164
void sendByte(int d)
{
  shiftOut(DATA, CLK, MSBFIRST, d);
}

//
// Subroutine for PD2437
//

// set address for PD2437
void setAddr(int adr)
{
  digitalWrite(A0, (adr&0x1));
  digitalWrite(A1, (adr&0x2));
  digitalWrite(A2, (adr&0x4));
} 

void putChar(int pos, int ch)
{
  digitalWrite(CE, LOW);

  setAddr(pos);
  sendByte(ch);
  digitalWrite(WR, LOW);
  digitalWrite(WR, HIGH); 
  digitalWrite(CE, HIGH);
}

PD2437은 매우 쉽게 여러개를 cascading이 가능하기 때문에 현재 총 10개의 PD2437을 연결하여 20x2 LED display를 만들어 볼까 생각중이다. LCD에 비해 직접 발광을 하기 때문에 시야각 문제도 없고 시중에서 구할 수 있는 20x2 LCD보다 크기도 크기 때문에 야간에도 글자를 정확하게 확인할 수 있기 때문에 signboard로 적합할 거 같다.